Debug.as

ステージ上にテキストフィールドを生成し、そこにtrace結果を出力する。
ブラウザ上でのデバッグ、検証に役立つはず。

実行方法: Debug.trace(〜);

/* ActionScript2 */

class Debug{

private static var _isInit:Boolean;
private static var _debugTf:TextField;
private static var _enableDisplay:Boolean = false;
private static var _enableWindow:Boolean = false;

private function Debug(){
}

/**
* デバッグの初期化
* @param	テキストフィールドをアタッチしたいMC（指定なしは_root）
* @param	ステージ上へのトレース許可（指定なしはtrue）
* @param	出力ウインドウへのトレース許可（指定なしはtrue）
*/
public static function init(mc:MovieClip, enableDisplay:Boolean, enableWindow:Boolean):Void{
Debug._enableDisplay = (enableDisplay==undefined)? true : enableDisplay;
Debug._enableWindow = (enableWindow==undefined)? true : enableWindow;
//テキストフィールドの生成（実行は1度だけ）
if(Debug._isInit){
return;
}
Debug._isInit = true;
var targMc:MovieClip = (mc)? mc : _root;
Debug._debugTf = targMc.createTextField("debug_tf",targMc.getNextHighestDepth(), 0,0,0,0);
Debug._debugTf.autoSize=true;
Debug._debugTf.multiline = true;//複数行許可（テキスト上をドラッグして古いのも見れる）
Debug._debugTf.textColor = 0x00FF00;
//一度ダミーのテキストを入れ、1行分の縦幅を調べる → autoSizeをオフにし、サイズをFIX。
Debug._debugTf.text = "TEST";
var tempHeight = Debug._debugTf._height;
Debug._debugTf.autoSize = false;
Debug._debugTf.text = "";
Debug._debugTf._height = tempHeight;
Debug._debugTf._width = Stage.width;
}

/**
* トレース処理
* @param	トレースしたいオブジェクト
*/
public static function trace(obj:Object):Void{
//initがまだ実行されていない時は実行する
if(!Debug._isInit){
Debug.init();
}
//ステージへ
if(Debug._enableDisplay){
Debug._debugTf.text += "n" + obj.toString();
//常に一番下の行へ移動する
Debug._debugTf.scroll = Debug._debugTf.maxscroll;
}
//出力ウィンドウへ
if(Debug._enableWindow){
trace(obj);
}
}

}

– asファイル
Debug.zip